mirror of
https://github.com/opencv/opencv.git
synced 2024-12-03 16:35:09 +08:00
1b0ff57562
Documentation generation refactoring (#10621) * Documentation build updates: - disable documentation by default, do not add to ALL target - combine Doxygen and Javadoc - optimize Doxygen html * javadoc: fix path in build directory * cmake: fix "Documentation" status line
59 lines
2.4 KiB
CMake
59 lines
2.4 KiB
CMake
project(${the_module}_jar)
|
|
|
|
set(OPENCV_JAVA_DIR "${CMAKE_CURRENT_BINARY_DIR}/opencv" CACHE INTERNAL "")
|
|
|
|
file(REMOVE_RECURSE "${OPENCV_JAVA_DIR}")
|
|
file(REMOVE "${OPENCV_DEPHELPER}/${the_module}_jar_source_copy")
|
|
|
|
file(MAKE_DIRECTORY "${OPENCV_JAVA_DIR}/build/classes")
|
|
set(java_src_dir "${OPENCV_JAVA_DIR}/java")
|
|
file(MAKE_DIRECTORY "${java_src_dir}")
|
|
|
|
set(JAR_NAME opencv-${OPENCV_JAVA_LIB_NAME_SUFFIX}.jar)
|
|
set(OPENCV_JAR_FILE "${OpenCV_BINARY_DIR}/bin/${JAR_NAME}" CACHE INTERNAL "")
|
|
|
|
ocv_copyfiles_append_dir(JAVA_SRC_COPY "${OPENCV_JAVA_BINDINGS_DIR}/gen/java" "${java_src_dir}")
|
|
|
|
set(depends gen_opencv_java_source "${OPENCV_DEPHELPER}/gen_opencv_java_source")
|
|
ocv_copyfiles_add_target(${the_module}_jar_source_copy JAVA_SRC_COPY "Copy Java(JAR) source files" ${depends})
|
|
set(depends ${the_module}_jar_source_copy "${OPENCV_DEPHELPER}/${the_module}_jar_source_copy")
|
|
|
|
configure_file("${CMAKE_CURRENT_SOURCE_DIR}/build.xml.in" "${OPENCV_JAVA_DIR}/build.xml" @ONLY)
|
|
list(APPEND depends "${OPENCV_JAVA_DIR}/build.xml")
|
|
|
|
add_custom_command(OUTPUT "${OPENCV_DEPHELPER}/${the_module}_jar"
|
|
COMMAND ${ANT_EXECUTABLE} -noinput -k jar
|
|
COMMAND ${CMAKE_COMMAND} -E touch "${OPENCV_DEPHELPER}/${the_module}_jar"
|
|
WORKING_DIRECTORY "${OPENCV_JAVA_DIR}"
|
|
DEPENDS ${depends}
|
|
COMMENT "Generating ${JAR_NAME}"
|
|
)
|
|
add_custom_target(${the_module}_jar DEPENDS "${OPENCV_DEPHELPER}/${the_module}_jar")
|
|
|
|
install(FILES ${OPENCV_JAR_FILE} OPTIONAL DESTINATION ${OPENCV_JAR_INSTALL_PATH} COMPONENT java)
|
|
|
|
add_dependencies(${the_module} ${the_module}_jar)
|
|
|
|
if(BUILD_DOCS)
|
|
add_custom_command(OUTPUT "${OPENCV_DEPHELPER}/${the_module}doc"
|
|
COMMAND ${ANT_EXECUTABLE} -noinput -k javadoc
|
|
COMMAND ${CMAKE_COMMAND} -E touch "${OPENCV_DEPHELPER}/${the_module}doc"
|
|
WORKING_DIRECTORY "${OPENCV_JAVA_DIR}"
|
|
DEPENDS ${depends}
|
|
COMMENT "Generating Javadoc"
|
|
)
|
|
add_custom_target(${the_module}doc DEPENDS "${OPENCV_DEPHELPER}/${the_module}doc")
|
|
install(DIRECTORY ${OpenCV_BINARY_DIR}/doc/doxygen/html/javadoc
|
|
DESTINATION "${OPENCV_DOC_INSTALL_PATH}/html"
|
|
COMPONENT "docs" OPTIONAL
|
|
${compatible_MESSAGE_NEVER}
|
|
)
|
|
set(CMAKE_DOXYGEN_JAVADOC_NODE
|
|
"<tab type=\"user\" url=\"./javadoc/index.html\" title=\"Java documentation\"/>"
|
|
CACHE INTERNAL "Link to the Java documentation") # set to the cache to make it global
|
|
add_custom_target(doxygen_javadoc DEPENDS ${the_module}doc)
|
|
add_dependencies(opencv_docs ${the_module}doc)
|
|
else()
|
|
unset(CMAKE_DOXYGEN_JAVADOC_NODE CACHE)
|
|
endif()
|