mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-12-17 09:37:55 +08:00
8de4ee858f
* add function get_cmake_vars * fine tuning. * apply to make based ports. * add log suffix on not windows platforms * fix c&p error * add previous LINK env * setup env on windows and extract cpp flags correctly. * Apply suggestions from code review * commit changes from fontconfig PR * Apply suggestions from code review Co-authored-by: nicole mazzuca <mazzucan@outlook.com> * cleanup docs * add conversion from somelib.lib to -lsomelib * add missing ar-lib wrapper * small but important regex correction * add latest changes from update_fontconfig PR * Apply suggestions from code review first set which don't need special attention Co-authored-by: ras0219 <533828+ras0219@users.noreply.github.com> * Apply suggestions from code review one more simple change Co-authored-by: ras0219 <533828+ras0219@users.noreply.github.com> * [x264] set env AS * fix bugs due to refactor * use subpath everywhere * apply changes from CR * remove unnecessary lines 41 & 44 * remove flag transformation * reintroduce the flag / to - transformation for MSVC * Apply suggestions from code review Co-authored-by: ras0219 <533828+ras0219@users.noreply.github.com> * rename the function * rename function/variables * transform flags list * Apply suggestions from code review * fix vcpkg_build_make due to the variable name change * fix another case of function renaming regressions * only rename config.log if it exists * actually add the script after vcpkg_common_functions was deleted. * remove setting of ldflags if path contains spaces Co-authored-by: nicole mazzuca <mazzucan@outlook.com> Co-authored-by: ras0219 <533828+ras0219@users.noreply.github.com>
215 lines
10 KiB
CMake
215 lines
10 KiB
CMake
## # vcpkg_build_make
|
|
##
|
|
## Build a linux makefile project.
|
|
##
|
|
## ## Usage:
|
|
## ```cmake
|
|
## vcpkg_build_make([BUILD_TARGET <target>]
|
|
## [ADD_BIN_TO_PATH]
|
|
## [ENABLE_INSTALL])
|
|
## [LOGFILE_ROOT <logfileroot>])
|
|
## ```
|
|
##
|
|
## ### BUILD_TARGET
|
|
## The target passed to the make build command (`./make <target>`). If not specified, the 'all' target will
|
|
## be passed.
|
|
##
|
|
## ### ADD_BIN_TO_PATH
|
|
## Adds the appropriate Release and Debug `bin\` directories to the path during the build such that executables can run against the in-tree DLLs.
|
|
##
|
|
## ### ENABLE_INSTALL
|
|
## IF the port supports the install target use vcpkg_install_make() instead of vcpkg_build_make()
|
|
##
|
|
## ### BUILD_TARGET
|
|
## The target passed to the make build command (`./make <target>`). If not specified, the 'all' target will
|
|
## be passed.
|
|
##
|
|
## ### DISABLE_PARALLEL
|
|
## The underlying buildsystem will be instructed to not parallelize
|
|
##
|
|
## ### SUBPATH
|
|
## Additional subdir to invoke make in. Useful if only parts of a port should be built.
|
|
##
|
|
## ## Notes:
|
|
## This command should be preceeded by a call to [`vcpkg_configure_make()`](vcpkg_configure_make.md).
|
|
## You can use the alias [`vcpkg_install_make()`](vcpkg_configure_make.md) function if your CMake script supports the
|
|
## "install" target
|
|
##
|
|
## ## Examples
|
|
##
|
|
## * [x264](https://github.com/Microsoft/vcpkg/blob/master/ports/x264/portfile.cmake)
|
|
## * [tcl](https://github.com/Microsoft/vcpkg/blob/master/ports/tcl/portfile.cmake)
|
|
## * [freexl](https://github.com/Microsoft/vcpkg/blob/master/ports/freexl/portfile.cmake)
|
|
## * [libosip2](https://github.com/Microsoft/vcpkg/blob/master/ports/libosip2/portfile.cmake)
|
|
function(vcpkg_build_make)
|
|
include("${_VCPKG_CMAKE_VARS_FILE}")
|
|
# parse parameters such that semicolons in options arguments to COMMAND don't get erased
|
|
cmake_parse_arguments(PARSE_ARGV 0 _bc "ADD_BIN_TO_PATH;ENABLE_INSTALL;DISABLE_PARALLEL" "LOGFILE_ROOT;BUILD_TARGET;SUBPATH" "")
|
|
|
|
if(NOT _bc_LOGFILE_ROOT)
|
|
set(_bc_LOGFILE_ROOT "build")
|
|
endif()
|
|
|
|
if(NOT _bc_BUILD_TARGET)
|
|
set(_bc_BUILD_TARGET "all")
|
|
endif()
|
|
|
|
if(WIN32)
|
|
set(_VCPKG_PREFIX ${CURRENT_PACKAGES_DIR})
|
|
set(_VCPKG_INSTALLED ${CURRENT_INSTALLED_DIR})
|
|
else()
|
|
string(REPLACE " " "\ " _VCPKG_PREFIX "${CURRENT_PACKAGES_DIR}")
|
|
string(REPLACE " " "\ " _VCPKG_INSTALLED "${CURRENT_INSTALLED_DIR}")
|
|
endif()
|
|
|
|
set(MAKE )
|
|
set(MAKE_OPTS )
|
|
set(INSTALL_OPTS )
|
|
if (CMAKE_HOST_WIN32)
|
|
set(PATH_GLOBAL "$ENV{PATH}")
|
|
vcpkg_add_to_path(PREPEND "${SCRIPTS}/buildsystems/make_wrapper")
|
|
vcpkg_acquire_msys(MSYS_ROOT)
|
|
find_program(MAKE make REQUIRED)
|
|
set(MAKE_COMMAND "${MAKE}")
|
|
set(MAKE_OPTS ${_bc_MAKE_OPTIONS} -j ${VCPKG_CONCURRENCY} --trace -f Makefile ${_bc_BUILD_TARGET})
|
|
set(NO_PARALLEL_MAKE_OPTS ${_bc_MAKE_OPTIONS} -j 1 --trace -f Makefile ${_bc_BUILD_TARGET})
|
|
|
|
string(REPLACE " " "\\\ " _VCPKG_PACKAGE_PREFIX ${CURRENT_PACKAGES_DIR})
|
|
# Don't know why '/cygdrive' is suddenly a requirement here. (at least for x264)
|
|
string(REGEX REPLACE "([a-zA-Z]):/" "/cygdrive/\\1/" _VCPKG_PACKAGE_PREFIX "${_VCPKG_PACKAGE_PREFIX}")
|
|
set(INSTALL_OPTS -j ${VCPKG_CONCURRENCY} --trace -f Makefile install DESTDIR=${_VCPKG_PACKAGE_PREFIX})
|
|
#TODO: optimize for install-data (release) and install-exec (release/debug)
|
|
else()
|
|
# Compiler requriements
|
|
find_program(MAKE make REQUIRED)
|
|
set(MAKE_COMMAND "${MAKE}")
|
|
# Set make command and install command
|
|
set(MAKE_OPTS ${_bc_MAKE_OPTIONS} V=1 -j ${VCPKG_CONCURRENCY} -f Makefile ${_bc_BUILD_TARGET})
|
|
set(NO_PARALLEL_MAKE_OPTS ${_bc_MAKE_OPTIONS} V=1 -j 1 -f Makefile ${_bc_BUILD_TARGET})
|
|
set(INSTALL_OPTS -j ${VCPKG_CONCURRENCY} -f Makefile install DESTDIR=${CURRENT_PACKAGES_DIR})
|
|
endif()
|
|
|
|
# Since includes are buildtype independent those are setup by vcpkg_configure_make
|
|
_vcpkg_backup_env_variables(LIB LIBPATH LIBRARY_PATH LD_LIBRARY_PATH)
|
|
|
|
foreach(BUILDTYPE "debug" "release")
|
|
if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL BUILDTYPE)
|
|
if(BUILDTYPE STREQUAL "debug")
|
|
# Skip debug generate
|
|
if (_VCPKG_NO_DEBUG)
|
|
continue()
|
|
endif()
|
|
set(SHORT_BUILDTYPE "-dbg")
|
|
set(CMAKE_BUILDTYPE "DEBUG")
|
|
set(PATH_SUFFIX "/debug")
|
|
else()
|
|
# In NO_DEBUG mode, we only use ${TARGET_TRIPLET} directory.
|
|
if (_VCPKG_NO_DEBUG)
|
|
set(SHORT_BUILDTYPE "")
|
|
else()
|
|
set(SHORT_BUILDTYPE "-rel")
|
|
endif()
|
|
set(CMAKE_BUILDTYPE "RELEASE")
|
|
set(PATH_SUFFIX "")
|
|
endif()
|
|
|
|
set(WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}${SHORT_BUILDTYPE}${_bc_SUBPATH}")
|
|
message(STATUS "Building ${TARGET_TRIPLET}${SHORT_BUILDTYPE}")
|
|
|
|
_vcpkg_extract_cpp_flags_and_set_cflags_and_cxxflags(${CMAKE_BUILDTYPE})
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
|
set(LINKER_FLAGS_${CMAKE_BUILDTYPE} "${VCPKG_DETECTED_STATIC_LINKERFLAGS_${CMAKE_BUILDTYPE}}")
|
|
else() # dynamic
|
|
set(LINKER_FLAGS_${CMAKE_BUILDTYPE} "${VCPKG_DETECTED_SHARED_LINKERFLAGS_${CMAKE_BUILDTYPE}}")
|
|
endif()
|
|
if (CMAKE_HOST_WIN32 AND VCPKG_DETECTED_C_COMPILER MATCHES "cl.exe")
|
|
set(LDFLAGS_${CMAKE_BUILDTYPE} "-L${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib -L${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib/manual-link")
|
|
set(LINK_ENV_${CMAKE_BUILDTYPE} "$ENV{_LINK_} ${LINKER_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
else()
|
|
set(LDFLAGS_${CMAKE_BUILDTYPE} "-L${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib -L${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib/manual-link ${LINKER_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
endif()
|
|
|
|
# Setup environment
|
|
set(ENV{CPPFLAGS} "${CPPFLAGS_${CMAKE_BUILDTYPE}}")
|
|
set(ENV{CFLAGS} "${CFLAGS_${CMAKE_BUILDTYPE}}")
|
|
set(ENV{CXXFLAGS} "${CXXFLAGS_${CMAKE_BUILDTYPE}}")
|
|
set(ENV{RCFLAGS} "${VCPKG_DETECTED_CMAKE_RC_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
set(ENV{LDFLAGS} "${LDFLAGS_${CMAKE_BUILDTYPE}}")
|
|
set(ENV{LIB} "${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib/${VCPKG_HOST_PATH_SEPARATOR}${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib/manual-link/${LIB_PATHLIKE_CONCAT}")
|
|
set(ENV{LIBPATH} "${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib/${VCPKG_HOST_PATH_SEPARATOR}${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib/manual-link/${LIBPATH_PATHLIKE_CONCAT}")
|
|
set(ENV{LIBRARY_PATH} "${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib/${VCPKG_HOST_PATH_SEPARATOR}${_VCPKG_INSTALLED}${PATH_SUFFIX}/lib/manual-link/${LIBRARY_PATH_PATHLIKE_CONCAT}")
|
|
#set(ENV{LD_LIBRARY_PATH} "${_VCPKG_INSTALLED}${PATH_SUFFIX_${BUILDTYPE}}/lib/${VCPKG_HOST_PATH_SEPARATOR}${_VCPKG_INSTALLED}${PATH_SUFFIX_${BUILDTYPE}}/lib/manual-link/${LD_LIBRARY_PATH_PATHLIKE_CONCAT}")
|
|
|
|
if(LINK_ENV_${_VAR_SUFFIX})
|
|
set(_LINK_CONFIG_BACKUP "$ENV{_LINK_}")
|
|
set(ENV{_LINK_} "${LINK_ENV_${_VAR_SUFFIX}}")
|
|
endif()
|
|
|
|
if(_bc_ADD_BIN_TO_PATH)
|
|
set(_BACKUP_ENV_PATH "$ENV{PATH}")
|
|
vcpkg_add_to_path(PREPEND "${CURRENT_INSTALLED_DIR}${PATH_SUFFIX}/bin")
|
|
endif()
|
|
|
|
if(MAKE_BASH)
|
|
set(MAKE_CMD_LINE "${MAKE_COMMAND} ${MAKE_OPTS}")
|
|
set(NO_PARALLEL_MAKE_CMD_LINE "${MAKE_COMMAND} ${NO_PARALLEL_MAKE_OPTS}")
|
|
else()
|
|
set(MAKE_CMD_LINE ${MAKE_COMMAND} ${MAKE_OPTS})
|
|
set(NO_PARALLEL_MAKE_CMD_LINE ${MAKE_COMMAND} ${NO_PARALLEL_MAKE_OPTS})
|
|
endif()
|
|
|
|
if (_bc_DISABLE_PARALLEL)
|
|
vcpkg_execute_build_process(
|
|
COMMAND ${MAKE_BASH} ${MAKE_CMD_LINE}
|
|
WORKING_DIRECTORY "${WORKING_DIRECTORY}"
|
|
LOGNAME "${_bc_LOGFILE_ROOT}-${TARGET_TRIPLET}${SHORT_BUILDTYPE}"
|
|
)
|
|
else()
|
|
vcpkg_execute_build_process(
|
|
COMMAND ${MAKE_BASH} ${MAKE_CMD_LINE}
|
|
NO_PARALLEL_COMMAND ${MAKE_BASH} ${NO_PARALLEL_MAKE_CMD_LINE}
|
|
WORKING_DIRECTORY "${WORKING_DIRECTORY}"
|
|
LOGNAME "${_bc_LOGFILE_ROOT}-${TARGET_TRIPLET}${SHORT_BUILDTYPE}"
|
|
)
|
|
endif()
|
|
|
|
if (_bc_ENABLE_INSTALL)
|
|
message(STATUS "Installing ${TARGET_TRIPLET}${SHORT_BUILDTYPE}")
|
|
if(MAKE_BASH)
|
|
set(MAKE_CMD_LINE "${MAKE_COMMAND} ${INSTALL_OPTS}")
|
|
else()
|
|
set(MAKE_CMD_LINE ${MAKE_COMMAND} ${INSTALL_OPTS})
|
|
endif()
|
|
vcpkg_execute_build_process(
|
|
COMMAND ${MAKE_BASH} ${MAKE_CMD_LINE}
|
|
WORKING_DIRECTORY "${WORKING_DIRECTORY}"
|
|
LOGNAME "install-${TARGET_TRIPLET}${SHORT_BUILDTYPE}"
|
|
)
|
|
endif()
|
|
|
|
if(_LINK_CONFIG_BACKUP)
|
|
set(ENV{_LINK_} "${_LINK_CONFIG_BACKUP}")
|
|
unset(_LINK_CONFIG_BACKUP)
|
|
endif()
|
|
|
|
if(_bc_ADD_BIN_TO_PATH)
|
|
set(ENV{PATH} "${_BACKUP_ENV_PATH}")
|
|
endif()
|
|
endif()
|
|
endforeach()
|
|
|
|
if (_bc_ENABLE_INSTALL)
|
|
string(REGEX REPLACE "([a-zA-Z]):/" "/\\1/" _VCPKG_INSTALL_PREFIX "${CURRENT_INSTALLED_DIR}")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}_tmp")
|
|
file(RENAME "${CURRENT_PACKAGES_DIR}" "${CURRENT_PACKAGES_DIR}_tmp")
|
|
file(RENAME "${CURRENT_PACKAGES_DIR}_tmp${_VCPKG_INSTALL_PREFIX}/" "${CURRENT_PACKAGES_DIR}")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}_tmp")
|
|
endif()
|
|
|
|
if (CMAKE_HOST_WIN32)
|
|
set(ENV{PATH} "${PATH_GLOBAL}")
|
|
endif()
|
|
|
|
_vcpkg_restore_env_variables(LIB LIBPATH LIBRARY_PATH LD_LIBRARY_PATH)
|
|
endfunction()
|