mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-12-04 09:49:25 +08:00
94b089b7c1
* Update to 3.1.5 * Add feature 'tools' * ilmbase is now imath * [theia] Use openimageio cmake config * [freeimage] Use OpenEXR 3 and Imath * [opencv4] Use upstream's OpenEXR 3 support * [opencv3] Use upstream's OpenEXR 3 support * [opencv2] Use OpenEXR 3 and Imath * [osg] Use OpenEXR 3 * [openvdb] Use Imath, enable OpenEXR * [pangolin] Use OpenEXR 3 * [directxtex] Use OpenEXR 3 * [uvatlas] Disable /guard:ehcont when directxtex uses openexr * Update versions Co-authored-by: chausner <chausner@users.noreply.github.com>
70 lines
2.5 KiB
CMake
70 lines
2.5 KiB
CMake
vcpkg_from_github(
|
|
OUT_SOURCE_PATH SOURCE_PATH
|
|
REPO AcademySoftwareFoundation/openvdb
|
|
REF 0ed0f19ea4fbb0d8bf64d3dca07abab3c7429803 # v9.0.0
|
|
SHA512 f033f2d5801327ab8aeffb12d1a74ff880e477a1f00da3b03a3087262a3e72ef77c13e05fe8e3c94a26721804230c0272d9ca069af997c36c992f3e2f3d962f2
|
|
PATCHES
|
|
0003-fix-cmake.patch
|
|
fix-Target-notfound.patch
|
|
)
|
|
|
|
file(REMOVE "${SOURCE_PATH}/cmake/FindTBB.cmake")
|
|
file(REMOVE "${SOURCE_PATH}/cmake/FindIlmBase.cmake")
|
|
file(REMOVE "${SOURCE_PATH}/cmake/FindBlosc.cmake")
|
|
file(REMOVE "${SOURCE_PATH}/cmake/FindOpenEXR.cmake")
|
|
|
|
string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "static" OPENVDB_STATIC)
|
|
string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "dynamic" OPENVDB_SHARED)
|
|
|
|
set(OPENVDB_BUILD_TOOLS OFF)
|
|
if ("tools" IN_LIST FEATURES)
|
|
if (VCPKG_LIBRARY_LINKAGE STREQUAL dynamic)
|
|
set(OPENVDB_BUILD_TOOLS ON)
|
|
else()
|
|
message(FATAL_ERROR "Unable to build tools if static libraries are required")
|
|
endif()
|
|
endif()
|
|
|
|
if ("ax" IN_LIST FEATURES)
|
|
if(NOT VCPKG_TARGET_IS_WINDOWS)
|
|
set(OPENVDB_BUILD_AX ON)
|
|
else()
|
|
message(FATAL_ERROR "Currently no support for building OpenVDB AX on Windows.")
|
|
endif()
|
|
endif()
|
|
|
|
vcpkg_cmake_configure(
|
|
SOURCE_PATH "${SOURCE_PATH}"
|
|
OPTIONS
|
|
-DOPENVDB_BUILD_UNITTESTS=OFF
|
|
-DOPENVDB_BUILD_PYTHON_MODULE=OFF
|
|
-DOPENVDB_ENABLE_3_ABI_COMPATIBLE=OFF
|
|
-DUSE_EXR=ON
|
|
-DUSE_GLFW3=ON
|
|
-DUSE_IMATH_HALF=ON
|
|
-DOPENVDB_CORE_STATIC=${OPENVDB_STATIC}
|
|
-DOPENVDB_CORE_SHARED=${OPENVDB_SHARED}
|
|
-DOPENVDB_BUILD_VDB_PRINT=${OPENVDB_BUILD_TOOLS}
|
|
-DOPENVDB_BUILD_VDB_VIEW=${OPENVDB_BUILD_TOOLS}
|
|
-DOPENVDB_BUILD_VDB_RENDER=${OPENVDB_BUILD_TOOLS}
|
|
-DOPENVDB_BUILD_VDB_LOD=${OPENVDB_BUILD_TOOLS}
|
|
-DUSE_PKGCONFIG=OFF
|
|
${OPENVDB_BUILD_AX}
|
|
)
|
|
|
|
vcpkg_cmake_install()
|
|
|
|
vcpkg_cmake_config_fixup(CONFIG_PATH lib/cmake/OpenVDB)
|
|
|
|
vcpkg_copy_pdbs()
|
|
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include" "${CURRENT_PACKAGES_DIR}/debug/share")
|
|
|
|
if (OPENVDB_BUILD_TOOLS)
|
|
vcpkg_copy_tools(TOOL_NAMES vdb_print vdb_render vdb_view vdb_lod AUTO_CLEAN)
|
|
endif()
|
|
|
|
configure_file("${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake.in" "${CURRENT_PACKAGES_DIR}/share/${PORT}/vcpkg-cmake-wrapper.cmake" @ONLY)
|
|
file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
|
|
file(INSTALL "${SOURCE_PATH}/openvdb/openvdb/COPYRIGHT" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
|