mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-12-02 16:49:10 +08:00
e7e328cf9d
* [many ports] call vcpkg_fixup_pkgconfig() The ports generate pc files, but don't call vcpkg_fixup_pkgconfig() so that there are absolute paths in the pc files * Update port-version for armadillo and polyclipping. * Update version database. Co-authored-by: Billy Robert O'Neal III <bion@microsoft.com>
68 lines
1.9 KiB
CMake
68 lines
1.9 KiB
CMake
vcpkg_fail_port_install(ON_TARGET "UWP")
|
|
|
|
vcpkg_from_github(
|
|
OUT_SOURCE_PATH SOURCE_PATH
|
|
REPO zeromq/libzmq
|
|
REF v4.3.4
|
|
SHA512 ad828b1ab5a87983285a6b44b08240816ed1c4e2c73306ab1a851bf80df1892b5e2f92064a49fbadc1f4c75043625ace77dd25b64d5d1c2a7d1d61cc916fba0b
|
|
PATCHES fix-arm.patch
|
|
)
|
|
|
|
string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "static" BUILD_STATIC)
|
|
string(COMPARE EQUAL "${VCPKG_LIBRARY_LINKAGE}" "dynamic" BUILD_SHARED)
|
|
|
|
vcpkg_check_features(
|
|
OUT_FEATURE_OPTIONS FEATURE_OPTIONS
|
|
FEATURES
|
|
sodium WITH_LIBSODIUM
|
|
draft ENABLE_DRAFTS
|
|
websockets-sha1 ENABLE_WS
|
|
)
|
|
|
|
set(PLATFORM_OPTIONS)
|
|
if(VCPKG_TARGET_IS_MINGW)
|
|
set(PLATFORM_OPTIONS "-DCMAKE_SYSTEM_VERSION=6.0")
|
|
endif()
|
|
|
|
vcpkg_cmake_configure(
|
|
SOURCE_PATH ${SOURCE_PATH}
|
|
OPTIONS
|
|
-DZMQ_BUILD_TESTS=OFF
|
|
-DBUILD_STATIC=${BUILD_STATIC}
|
|
-DBUILD_SHARED=${BUILD_SHARED}
|
|
-DWITH_PERF_TOOL=OFF
|
|
-DWITH_DOCS=OFF
|
|
-DWITH_NSS=OFF
|
|
-DWITH_LIBSODIUM_STATIC=${BUILD_STATIC}
|
|
${FEATURE_OPTIONS}
|
|
${PLATFORM_OPTIONS}
|
|
OPTIONS_DEBUG
|
|
"-DCMAKE_PDB_OUTPUT_DIRECTORY=${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}-dbg"
|
|
)
|
|
|
|
vcpkg_cmake_install()
|
|
|
|
vcpkg_copy_pdbs()
|
|
|
|
if(VCPKG_TARGET_IS_WINDOWS)
|
|
vcpkg_cmake_config_fixup(CONFIG_PATH CMake)
|
|
else()
|
|
vcpkg_cmake_config_fixup(CONFIG_PATH lib/cmake/ZeroMQ)
|
|
endif()
|
|
|
|
file(COPY
|
|
"${CMAKE_CURRENT_LIST_DIR}/vcpkg-cmake-wrapper.cmake"
|
|
DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}"
|
|
)
|
|
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/bin" "${CURRENT_PACKAGES_DIR}/debug/bin")
|
|
endif()
|
|
|
|
# Handle copyright
|
|
file(RENAME "${CURRENT_PACKAGES_DIR}/share/zmq/COPYING.LESSER.txt" "${CURRENT_PACKAGES_DIR}/share/${PORT}/copyright")
|
|
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include" "${CURRENT_PACKAGES_DIR}/debug/share" "${CURRENT_PACKAGES_DIR}/share/zmq")
|
|
|
|
vcpkg_fixup_pkgconfig()
|