mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-12-04 18:11:28 +08:00
afa41496eb
Fixes #36776, update `mongo-c-driver` and `libbson` to 1.26.0. mongo-c-driver - All features are tested successfully in the following triplet: ``` x86-windows x64-windows x64-windows-static ``` The usage test passed on `x64-windows` (header files found): ``` mongo-c-driver provides CMake targets: find_package(mongoc-1.0 CONFIG REQUIRED) target_link_libraries(main PRIVATE $<IF:$<TARGET_EXISTS:mongo::mongoc_shared>,mongo::mongoc_shared,mongo::mongoc_static>) ``` - [x] Changes comply with the [maintainer guide](https://github.com/microsoft/vcpkg-docs/blob/main/vcpkg/contributing/maintainer-guide.md). - [x] SHA512s are updated for each updated download. - [ ] ~The "supports" clause reflects platforms that may be fixed by this new version.~ - [ ] ~Any fixed [CI baseline](https://github.com/microsoft/vcpkg/blob/master/scripts/ci.baseline.txt) entries are removed from that file.~ - [ ] ~Any patches that are no longer applied are deleted from the port's directory.~ - [x] The version database is fixed by rerunning `./vcpkg x-add-version --all` and committing the result. - [x] Only one version is added to each modified port's versions file. --------- Co-authored-by: Monica <v-liumonica@microsoft.com>
90 lines
3.0 KiB
CMake
90 lines
3.0 KiB
CMake
# This port needs to be updated at the same time as libbson
|
|
vcpkg_from_github(
|
|
OUT_SOURCE_PATH SOURCE_PATH
|
|
REPO mongodb/mongo-c-driver
|
|
REF "${VERSION}"
|
|
SHA512 3ad7ad67284b8900432c8df6b00a96bb8ee265a0d8bdf689d7ab48a0949fd14f69deff30c6db86d39f9a1729e4884d8e91eb2d21dfc5172a3edb3d950df432fd
|
|
HEAD_REF master
|
|
PATCHES
|
|
disable-dynamic-when-static.patch
|
|
fix-dependencies.patch
|
|
fix-include-directory.patch
|
|
fix-mingw.patch
|
|
)
|
|
file(WRITE "${SOURCE_PATH}/VERSION_CURRENT" "${VERSION}")
|
|
|
|
# Cannot use string(COMPARE EQUAL ...)
|
|
set(ENABLE_STATIC OFF)
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
|
set(ENABLE_STATIC ON)
|
|
endif()
|
|
|
|
vcpkg_check_features(OUT_FEATURE_OPTIONS OPTIONS
|
|
FEATURES
|
|
icu ENABLE_ICU
|
|
snappy ENABLE_SNAPPY
|
|
zstd ENABLE_ZSTD
|
|
)
|
|
|
|
if("openssl" IN_LIST FEATURES)
|
|
list(APPEND OPTIONS -DENABLE_SSL=OPENSSL)
|
|
elseif(VCPKG_TARGET_IS_WINDOWS)
|
|
list(APPEND OPTIONS -DENABLE_SSL=WINDOWS)
|
|
elseif(VCPKG_TARGET_IS_OSX OR VCPKG_TARGET_IS_IOS)
|
|
list(APPEND OPTIONS -DENABLE_SSL=DARWIN)
|
|
else()
|
|
list(APPEND OPTIONS -DENABLE_SSL=OFF)
|
|
endif()
|
|
|
|
if(VCPKG_TARGET_IS_ANDROID)
|
|
vcpkg_list(APPEND OPTIONS -DENABLE_SRV=OFF)
|
|
endif()
|
|
|
|
vcpkg_cmake_configure(
|
|
SOURCE_PATH "${SOURCE_PATH}"
|
|
DISABLE_PARALLEL_CONFIGURE
|
|
OPTIONS
|
|
${OPTIONS}
|
|
"-DBUILD_VERSION=${VERSION}"
|
|
-DUSE_SYSTEM_LIBBSON=ON
|
|
-DENABLE_EXAMPLES=OFF
|
|
-DENABLE_SHM_COUNTERS=OFF
|
|
-DENABLE_STATIC=${ENABLE_STATIC}
|
|
-DENABLE_TESTS=OFF
|
|
-DENABLE_UNINSTALL=OFF
|
|
-DENABLE_ZLIB=SYSTEM
|
|
-DVCPKG_HOST_TRIPLET=${HOST_TRIPLET} # for host pkgconf in PATH
|
|
-DCMAKE_DISABLE_FIND_PACKAGE_Python=ON
|
|
-DCMAKE_DISABLE_FIND_PACKAGE_Python3=ON
|
|
MAYBE_UNUSED_VARIABLES
|
|
ENABLE_ICU
|
|
)
|
|
vcpkg_cmake_install()
|
|
vcpkg_copy_pdbs()
|
|
vcpkg_fixup_pkgconfig()
|
|
|
|
vcpkg_cmake_config_fixup(PACKAGE_NAME mongoc-1.0 CONFIG_PATH "lib/cmake/mongoc-1.0" DO_NOT_DELETE_PARENT_CONFIG_PATH)
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
|
vcpkg_replace_string("${CURRENT_PACKAGES_DIR}/include/mongoc/mongoc-macros.h"
|
|
"#define MONGOC_MACROS_H" "#define MONGOC_MACROS_H\n#ifndef MONGOC_STATIC\n#define MONGOC_STATIC\n#endif")
|
|
vcpkg_cmake_config_fixup(PACKAGE_NAME libmongoc-static-1.0 CONFIG_PATH "lib/cmake/libmongoc-static-1.0")
|
|
file(MAKE_DIRECTORY "${CURRENT_PACKAGES_DIR}/share/libmongoc-1.0")
|
|
file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/libmongoc-1.0-config.cmake" DESTINATION "${CURRENT_PACKAGES_DIR}/share/libmongoc-1.0")
|
|
else()
|
|
vcpkg_cmake_config_fixup(PACKAGE_NAME libmongoc-1.0 CONFIG_PATH "lib/cmake/libmongoc-1.0")
|
|
endif()
|
|
|
|
file(REMOVE_RECURSE
|
|
"${CURRENT_PACKAGES_DIR}/debug/include"
|
|
"${CURRENT_PACKAGES_DIR}/debug/share"
|
|
)
|
|
|
|
file(INSTALL "${CMAKE_CURRENT_LIST_DIR}/usage" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}")
|
|
|
|
vcpkg_install_copyright(
|
|
FILE_LIST
|
|
"${SOURCE_PATH}/COPYING"
|
|
"${SOURCE_PATH}/THIRD_PARTY_NOTICES"
|
|
"${SOURCE_PATH}/src/libmongoc/THIRD_PARTY_NOTICES"
|
|
)
|