mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-11-25 02:49:01 +08:00
83a4bd802f
* [kf5texteditor] create a port with v5.98.0 * [kf5texteditor] fix install errors * [kf5texteditor] update baseline * [kf5texteditor] fix windows build * [kf5texteditor] find gettext(host) tools * [kf5texteditor] update baseline * Update ports/kf5texteditor/vcpkg.json Co-authored-by: Kai Pastor <dg0yt@darc.de> * [kf5texteditor] use VCPKG_HOST_TRIPLET * [kf5parts] install .desktop to share/kservicetypes5 * [kf5service] install .desktop to share/kservicetypes5 * [kf5texteditor] use changed kf5ports, kf5services --------- Co-authored-by: Kai Pastor <dg0yt@darc.de>
73 lines
2.4 KiB
CMake
73 lines
2.4 KiB
CMake
vcpkg_from_github(
|
|
OUT_SOURCE_PATH SOURCE_PATH
|
|
REPO KDE/kservice
|
|
REF v5.98.0
|
|
SHA512 c2cfe77418099883838deb3b4143a48e31845f8ea81b335fe86214d23c3df3233be96037e104593dd852b10363a0f2dd28d7cfa04ced608881c77f8a6524f83f
|
|
HEAD_REF master
|
|
)
|
|
|
|
if(VCPKG_TARGET_IS_OSX)
|
|
# On Darwin platform, the bundled version of 'bison' may be too old (< 3.0).
|
|
vcpkg_find_acquire_program(BISON)
|
|
execute_process(
|
|
COMMAND ${BISON} --version
|
|
OUTPUT_VARIABLE BISON_OUTPUT
|
|
)
|
|
string(REGEX MATCH "([0-9]+)\\.([0-9]+)\\.([0-9]+)" BISON_VERSION "${BISON_OUTPUT}")
|
|
set(BISON_MAJOR ${CMAKE_MATCH_1})
|
|
set(BISON_MINOR ${CMAKE_MATCH_2})
|
|
message(STATUS "Using bison: ${BISON_MAJOR}.${BISON_MINOR}.${CMAKE_MATCH_3}")
|
|
if(NOT (BISON_MAJOR GREATER_EQUAL 3 AND BISON_MINOR GREATER_EQUAL 0))
|
|
message(WARNING "${PORT} requires bison version greater than one provided by macOS, please use \`brew install bison\` to install a newer bison.")
|
|
endif()
|
|
endif()
|
|
|
|
vcpkg_find_acquire_program(BISON)
|
|
vcpkg_find_acquire_program(FLEX)
|
|
|
|
get_filename_component(FLEX_DIR "${FLEX}" DIRECTORY)
|
|
get_filename_component(BISON_DIR "${BISON}" DIRECTORY)
|
|
|
|
vcpkg_add_to_path(PREPEND "${FLEX_DIR}")
|
|
vcpkg_add_to_path(PREPEND "${BISON_DIR}")
|
|
|
|
# Prevent KDEClangFormat from writing to source effectively blocking parallel configure
|
|
file(WRITE "${SOURCE_PATH}/.clang-format" "DisableFormat: true\nSortIncludes: false\n")
|
|
|
|
# See ECM/kde-modules/KDEInstallDirs5.cmake
|
|
# Relocate .desktop files for next ports
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
|
list(APPEND KDE_OPTIONS
|
|
-DKDE_INSTALL_KSERVICES5DIR="share/kservices5"
|
|
-DKDE_INSTALL_KSERVICETYPES5DIR="share/kservicetypes5"
|
|
)
|
|
endif()
|
|
|
|
vcpkg_cmake_configure(
|
|
SOURCE_PATH "${SOURCE_PATH}"
|
|
OPTIONS
|
|
-DBUILD_TESTING=OFF
|
|
-DCMAKE_DISABLE_FIND_PACKAGE_KF5DocTools=ON
|
|
${KDE_OPTIONS}
|
|
)
|
|
|
|
vcpkg_cmake_install()
|
|
vcpkg_cmake_config_fixup(PACKAGE_NAME KF5Service CONFIG_PATH lib/cmake/KF5Service)
|
|
vcpkg_copy_pdbs()
|
|
|
|
vcpkg_copy_tools(
|
|
TOOL_NAMES kbuildsycoca5
|
|
AUTO_CLEAN
|
|
)
|
|
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/bin" "${CURRENT_PACKAGES_DIR}/debug/bin")
|
|
endif()
|
|
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
|
|
|
|
file(GLOB LICENSE_FILES "${SOURCE_PATH}/LICENSES/*")
|
|
vcpkg_install_copyright(FILE_LIST ${LICENSE_FILES})
|
|
|