mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-12-02 15:41:48 +08:00
9030cccff3
* Update onnx to 1.10.1 * Update CI baseline Co-authored-by: chausner <chausner@users.noreply.github.com>
98 lines
3.5 KiB
CMake
98 lines
3.5 KiB
CMake
# uwp: LOAD_LIBRARY_SEARCH_DEFAULT_DIRS undefined identifier
|
|
vcpkg_fail_port_install(ON_TARGET "uwp")
|
|
vcpkg_check_linkage(ONLY_STATIC_LIBRARY)
|
|
|
|
vcpkg_from_github(
|
|
OUT_SOURCE_PATH SOURCE_PATH
|
|
REPO onnx/onnx
|
|
REF v1.10.1
|
|
SHA512 927b6d74dcf41b62c1290674cebb8e6c054acf101214352a0c5414d9b2eafa2d1e144f4d361452cd7494fb228e26c2ce2676fb1212aff1eeb3f889dc2faf5438
|
|
PATCHES
|
|
fix-cmakelists.patch
|
|
wrap-onnxifi-targets.patch
|
|
)
|
|
|
|
if(VCPKG_TARGET_IS_WINDOWS)
|
|
string(COMPARE EQUAL "${VCPKG_CRT_LINKAGE}" "static" USE_STATIC_RUNTIME)
|
|
list(APPEND PLATFORM_OPTIONS
|
|
-DONNX_USE_MSVC_STATIC_RUNTIME=${USE_STATIC_RUNTIME}
|
|
)
|
|
endif()
|
|
|
|
# ONNX_USE_PROTOBUF_SHARED_LIBS: find the library and check its file extension
|
|
find_library(PROTOBUF_LIBPATH NAMES protobuf PATHS "${CURRENT_INSTALLED_DIR}/bin" "${CURRENT_INSTALLED_DIR}/lib" REQUIRED)
|
|
get_filename_component(PROTOBUF_LIBNAME "${PROTOBUF_LIBPATH}" NAME)
|
|
if(PROTOBUF_LIBNAME MATCHES "${CMAKE_SHARED_LIBRARY_SUFFIX}")
|
|
set(USE_PROTOBUF_SHARED ON)
|
|
else()
|
|
set(USE_PROTOBUF_SHARED OFF)
|
|
endif()
|
|
|
|
vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
|
|
FEATURES
|
|
pybind11 BUILD_ONNX_PYTHON
|
|
)
|
|
|
|
# Like protoc, python is required for codegen.
|
|
vcpkg_find_acquire_program(PYTHON3)
|
|
|
|
# PATH for .bat scripts can find 'python'
|
|
get_filename_component(PYTHON_DIR "${PYTHON3}" PATH)
|
|
vcpkg_add_to_path(PREPEND "${PYTHON_DIR}")
|
|
|
|
if("pybind11" IN_LIST FEATURES)
|
|
# When BUILD_ONNX_PYTHON, we need Development component. Give a hint for FindPython3
|
|
list(APPEND FEATURE_OPTIONS
|
|
"-DPython3_ROOT_DIR=${CURRENT_INSTALLED_DIR}"
|
|
)
|
|
endif()
|
|
|
|
vcpkg_cmake_configure(
|
|
SOURCE_PATH "${SOURCE_PATH}"
|
|
OPTIONS
|
|
${FEATURE_OPTIONS} ${PLATFORM_OPTIONS}
|
|
-DPython3_EXECUTABLE=${PYTHON3}
|
|
-DONNX_ML=ON
|
|
-DONNX_GEN_PB_TYPE_STUBS=ON
|
|
-DONNX_USE_PROTOBUF_SHARED_LIBS=${USE_PROTOBUF_SHARED}
|
|
-DONNX_USE_LITE_PROTO=OFF
|
|
-DONNXIFI_ENABLE_EXT=OFF
|
|
-DONNX_BUILD_TESTS=OFF
|
|
-DONNX_BUILD_BENCHMARKS=OFF
|
|
)
|
|
|
|
if("pybind11" IN_LIST FEATURES)
|
|
# This target is not in install/export
|
|
vcpkg_cmake_build(TARGET onnx_cpp2py_export)
|
|
endif()
|
|
vcpkg_cmake_install()
|
|
vcpkg_cmake_config_fixup(CONFIG_PATH lib/cmake/ONNX)
|
|
|
|
file(INSTALL "${SOURCE_PATH}/LICENSE" DESTINATION "${CURRENT_PACKAGES_DIR}/share/${PORT}" RENAME copyright)
|
|
|
|
file(REMOVE_RECURSE
|
|
"${CURRENT_PACKAGES_DIR}/debug/include"
|
|
"${CURRENT_PACKAGES_DIR}/debug/share"
|
|
# the others are empty
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/backend"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/bin"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/controlflow"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/generator"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/logical"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/math"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/nn"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/object_detection"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/optional"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/quantization"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/reduction"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/rnn"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/sequence"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/traditionalml"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/defs/training"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/examples"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/frontend"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/onnx_cpp2py_export"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/test"
|
|
"${CURRENT_PACKAGES_DIR}/include/onnx/tools"
|
|
)
|