mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-12-17 18:17:51 +08:00
9c0956e573
while playing with qtbase on x64-uwp i found that it could not pass a try_compile command since important variables are not correctly forwarded. As such I concluded that the handling of try_compile in vcpkg is completely wrong.
74 lines
3.1 KiB
CMake
74 lines
3.1 KiB
CMake
set(ANDROID_CPP_FEATURES "rtti exceptions" CACHE STRING "")
|
|
set(CMAKE_SYSTEM_NAME Android CACHE STRING "")
|
|
set(ANDROID_TOOLCHAIN clang CACHE STRING "")
|
|
set(ANDROID_NATIVE_API_LEVEL ${CMAKE_SYSTEM_VERSION} CACHE STRING "")
|
|
if(CMAKE_SYSTEM_VERSION MATCHES "^[0-9]+$")
|
|
set(ANDROID_PLATFORM android-${CMAKE_SYSTEM_VERSION} CACHE STRING "")
|
|
else()
|
|
set(ANDROID_PLATFORM ${CMAKE_SYSTEM_VERSION} CACHE STRING "")
|
|
endif()
|
|
set(CMAKE_ANDROID_NDK_TOOLCHAIN_VERSION clang CACHE STRING "")
|
|
|
|
if (VCPKG_CRT_LINKAGE STREQUAL "dynamic")
|
|
set(ANDROID_STL c++_shared CACHE STRING "")
|
|
else()
|
|
set(ANDROID_STL c++_static CACHE STRING "")
|
|
endif()
|
|
|
|
if(DEFINED ENV{ANDROID_NDK_HOME})
|
|
set(ANDROID_NDK_HOME $ENV{ANDROID_NDK_HOME})
|
|
else()
|
|
set(ANDROID_NDK_HOME "$ENV{ProgramData}/Microsoft/AndroidNDK64/android-ndk-r13b/")
|
|
if(NOT EXISTS "${ANDROID_NDK_HOME}")
|
|
# Use Xamarin default installation folder
|
|
set(ANDROID_NDK_HOME "$ENV{ProgramFiles\(x86\)}/Android/android-sdk/ndk-bundle")
|
|
endif()
|
|
endif()
|
|
|
|
if(NOT EXISTS "${ANDROID_NDK_HOME}/build/cmake/android.toolchain.cmake")
|
|
message(FATAL_ERROR "Could not find android ndk. Searched at ${ANDROID_NDK_HOME}")
|
|
endif()
|
|
|
|
include("${ANDROID_NDK_HOME}/build/cmake/android.toolchain.cmake")
|
|
|
|
if(NOT _VCPKG_ANDROID_TOOLCHAIN)
|
|
set(_VCPKG_ANDROID_TOOLCHAIN 1)
|
|
|
|
if(POLICY CMP0056)
|
|
cmake_policy(SET CMP0056 NEW)
|
|
endif()
|
|
if(POLICY CMP0066)
|
|
cmake_policy(SET CMP0066 NEW)
|
|
endif()
|
|
if(POLICY CMP0067)
|
|
cmake_policy(SET CMP0067 NEW)
|
|
endif()
|
|
if(POLICY CMP0137)
|
|
cmake_policy(SET CMP0137 NEW)
|
|
endif()
|
|
list(APPEND CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
|
|
VCPKG_CRT_LINKAGE VCPKG_TARGET_ARCHITECTURE
|
|
VCPKG_C_FLAGS VCPKG_CXX_FLAGS
|
|
VCPKG_C_FLAGS_DEBUG VCPKG_CXX_FLAGS_DEBUG
|
|
VCPKG_C_FLAGS_RELEASE VCPKG_CXX_FLAGS_RELEASE
|
|
VCPKG_LINKER_FLAGS VCPKG_LINKER_FLAGS_RELEASE VCPKG_LINKER_FLAGS_DEBUG
|
|
)
|
|
|
|
string(APPEND CMAKE_C_FLAGS " -fPIC ${VCPKG_C_FLAGS} ")
|
|
string(APPEND CMAKE_CXX_FLAGS " -fPIC ${VCPKG_CXX_FLAGS} ")
|
|
string(APPEND CMAKE_C_FLAGS_DEBUG " ${VCPKG_C_FLAGS_DEBUG} ")
|
|
string(APPEND CMAKE_CXX_FLAGS_DEBUG " ${VCPKG_CXX_FLAGS_DEBUG} ")
|
|
string(APPEND CMAKE_C_FLAGS_RELEASE " ${VCPKG_C_FLAGS_RELEASE} ")
|
|
string(APPEND CMAKE_CXX_FLAGS_RELEASE " ${VCPKG_CXX_FLAGS_RELEASE} ")
|
|
|
|
string(APPEND CMAKE_MODULE_LINKER_FLAGS " ${VCPKG_LINKER_FLAGS} ")
|
|
string(APPEND CMAKE_SHARED_LINKER_FLAGS " ${VCPKG_LINKER_FLAGS} ")
|
|
string(APPEND CMAKE_EXE_LINKER_FLAGS " ${VCPKG_LINKER_FLAGS} ")
|
|
string(APPEND CMAKE_MODULE_LINKER_FLAGS_DEBUG " ${VCPKG_LINKER_FLAGS_DEBUG} ")
|
|
string(APPEND CMAKE_SHARED_LINKER_FLAGS_DEBUG " ${VCPKG_LINKER_FLAGS_DEBUG} ")
|
|
string(APPEND CMAKE_EXE_LINKER_FLAGS_DEBUG " ${VCPKG_LINKER_FLAGS_DEBUG} ")
|
|
string(APPEND CMAKE_MODULE_LINKER_FLAGS_RELEASE " ${VCPKG_LINKER_FLAGS_RELEASE} ")
|
|
string(APPEND CMAKE_SHARED_LINKER_FLAGS_RELEASE " ${VCPKG_LINKER_FLAGS_RELEASE} ")
|
|
string(APPEND CMAKE_EXE_LINKER_FLAGS_RELEASE " ${VCPKG_LINKER_FLAGS_RELEASE} ")
|
|
endif()
|