mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-11-27 08:29:06 +08:00
27c6c94202
* update all 16 configure_make ports * add make wrappers for msvc * improve make builds * fix relativ path errors on linux (and osx?) * revisit all 16 portfiles again * remove trace from install * fix relative build path issues. * bump control of the 16 configure ports * never forget .... real linux is case sensitive .... * Revert "bump control of the 16 configure ports" This reverts commit40d6d81c01. * Revert "Revert "bump control of the 16 configure ports"" This reverts commit9c9851ddfc. * bump control again for real ci rebuild * add copy_source * remove message * pass parameters to vcpkg_build_make * fix healpix build. * fix libmagic regression * fix libwandio regression * pfring changes regression fix? (cannot test in wsl) * ws change to retrigger CI * fix libpq regression * fix libudns regression * add share/pkgconfig to PKG_CONFIG_PATH * cleanup of deprecated options * cleanup docs * Revert "bump control again for real ci rebuild" This reverts commitb4bc18edc2. * shared binaries on linux should stay in lib. Only dlls are mvoed to bin * move pkgconfig check and add message about missing system packages * added autopoint as a build requirement * fix prerun shell working dir. * a few fixes from the x windows pr - add libpath setting - fixed pkgconfig search on windows platforms - fixed autopoint msys package on windows * fix release prefix * minimal cleanup and ws changes to trigger true CI rebuild * fix tcl by upgrading * remove unnecessary rename * fix pfring? can't test in WSL. Linux kernel headers required. * fix lowercase in patch * fix libwandio * remove x264 from fail list * replace wrappers with wrappers from automake * update make ports * remove unnecessary message * refactor vcpkg_configure_make * [tcl] remove stray ? * [farmhash] fix build * [freexl] ws change to retrigger ci build * [x264] add pthread as a dependency * [vcpkg/scripts] add ignore flag correctly * [sdl] fix vcpkg_fixup_pkgconfig call * [farmhash/freexl] delete configure and recreate it. * [libudns] remove trailing ? * [freexl] use empty build target * [freexl] add system library; remove previous change * Update ports/x264/portfile.cmake Co-authored-by: Jack·Boos·Yu <47264268+JackBoosY@users.noreply.github.com> * [libwandio] remove unncessary comment Co-authored-by: dan-shaw <51385773+dan-shaw@users.noreply.github.com> Co-authored-by: Jack·Boos·Yu <47264268+JackBoosY@users.noreply.github.com>
272 lines
12 KiB
CMake
272 lines
12 KiB
CMake
## # vcpkg_build_make
|
|
##
|
|
## Build a linux makefile project.
|
|
##
|
|
## ## Usage:
|
|
## ```cmake
|
|
## vcpkg_build_make([BUILD_TARGET <target>]
|
|
## [ADD_BIN_TO_PATH]
|
|
## [ENABLE_INSTALL])
|
|
## [LOGFILE_ROOT <logfileroot>])
|
|
## ```
|
|
##
|
|
## ### BUILD_TARGET
|
|
## The target passed to the make build command (`./make <target>`). If not specified, the 'all' target will
|
|
## be passed.
|
|
##
|
|
## ### ADD_BIN_TO_PATH
|
|
## Adds the appropriate Release and Debug `bin\` directories to the path during the build such that executables can run against the in-tree DLLs.
|
|
##
|
|
## ### ENABLE_INSTALL
|
|
## IF the port supports the install target use vcpkg_install_make() instead of vcpkg_build_make()
|
|
##
|
|
## ### BUILD_TARGET
|
|
## The target passed to the make build command (`./make <target>`). If not specified, the 'all' target will
|
|
## be passed.
|
|
##
|
|
## ## Notes:
|
|
## This command should be preceeded by a call to [`vcpkg_configure_make()`](vcpkg_configure_make.md).
|
|
## You can use the alias [`vcpkg_install_make()`](vcpkg_configure_make.md) function if your CMake script supports the
|
|
## "install" target
|
|
##
|
|
## ## Examples
|
|
##
|
|
## * [x264](https://github.com/Microsoft/vcpkg/blob/master/ports/x264/portfile.cmake)
|
|
## * [tcl](https://github.com/Microsoft/vcpkg/blob/master/ports/tcl/portfile.cmake)
|
|
## * [freexl](https://github.com/Microsoft/vcpkg/blob/master/ports/freexl/portfile.cmake)
|
|
## * [libosip2](https://github.com/Microsoft/vcpkg/blob/master/ports/libosip2/portfile.cmake)
|
|
function(vcpkg_build_make)
|
|
cmake_parse_arguments(_bc "ADD_BIN_TO_PATH;ENABLE_INSTALL" "LOGFILE_ROOT;BUILD_TARGET" "" ${ARGN})
|
|
|
|
if(NOT _bc_LOGFILE_ROOT)
|
|
set(_bc_LOGFILE_ROOT "build")
|
|
endif()
|
|
|
|
if(NOT _bc_BUILD_TARGET)
|
|
set(_bc_BUILD_TARGET "all")
|
|
endif()
|
|
|
|
if(WIN32)
|
|
set(_VCPKG_PREFIX ${CURRENT_PACKAGES_DIR})
|
|
set(_VCPKG_INSTALLED ${CURRENT_INSTALLED_DIR})
|
|
else()
|
|
string(REPLACE " " "\ " _VCPKG_PREFIX "${CURRENT_PACKAGES_DIR}")
|
|
string(REPLACE " " "\ " _VCPKG_INSTALLED "${CURRENT_INSTALLED_DIR}")
|
|
endif()
|
|
|
|
set(MAKE )
|
|
set(MAKE_OPTS )
|
|
set(INSTALL_OPTS )
|
|
if (CMAKE_HOST_WIN32)
|
|
set(PATH_GLOBAL "$ENV{PATH}")
|
|
# These should be moved into the portfile!
|
|
# vcpkg_find_acquire_program(YASM)
|
|
# get_filename_component(YASM_EXE_PATH ${YASM} DIRECTORY)
|
|
# vcpkg_add_to_path("${YASM_EXE_PATH}")
|
|
# vcpkg_find_acquire_program(PERL)
|
|
# get_filename_component(PERL_EXE_PATH ${PERL} DIRECTORY)
|
|
# vcpkg_add_to_path("${PERL_EXE_PATH}")
|
|
|
|
vcpkg_add_to_path(PREPEND "${SCRIPTS}/buildsystems/make_wrapper")
|
|
vcpkg_acquire_msys(MSYS_ROOT)
|
|
find_program(MAKE make REQUIRED) #mingw32-make
|
|
set(MAKE_COMMAND "${MAKE}")
|
|
set(MAKE_OPTS ${_bc_MAKE_OPTIONS} -j ${VCPKG_CONCURRENCY} --trace -f Makefile ${_bc_BUILD_TARGET})
|
|
|
|
string(REPLACE " " "\\\ " _VCPKG_PACKAGE_PREFIX ${CURRENT_PACKAGES_DIR})
|
|
string(REGEX REPLACE "([a-zA-Z]):/" "/\\1/" _VCPKG_PACKAGE_PREFIX "${_VCPKG_PACKAGE_PREFIX}")
|
|
set(INSTALL_OPTS -j ${VCPKG_CONCURRENCY} --trace -f Makefile install DESTDIR=${_VCPKG_PACKAGE_PREFIX})
|
|
#TODO: optimize for install-data (release) and install-exec (release/debug)
|
|
else()
|
|
# Compiler requriements
|
|
# set(MAKE_BASH)
|
|
find_program(MAKE make REQUIRED)
|
|
set(MAKE_COMMAND "${MAKE}")
|
|
# Set make command and install command
|
|
set(MAKE_OPTS ${_bc_MAKE_OPTIONS} V=1 -j ${VCPKG_CONCURRENCY} -f Makefile ${_bc_BUILD_TARGET})
|
|
set(INSTALL_OPTS -j ${VCPKG_CONCURRENCY} install DESTDIR=${CURRENT_PACKAGES_DIR})
|
|
endif()
|
|
|
|
# Backup enviromnent variables
|
|
set(C_FLAGS_BACKUP "$ENV{CFLAGS}")
|
|
set(CXX_FLAGS_BACKUP "$ENV{CXXFLAGS}")
|
|
set(LD_FLAGS_BACKUP "$ENV{LDFLAGS}")
|
|
set(INCLUDE_PATH_BACKUP "$ENV{INCLUDE_PATH}")
|
|
set(INCLUDE_BACKUP "$ENV{INCLUDE}")
|
|
set(C_INCLUDE_PATH_BACKUP "$ENV{C_INCLUDE_PATH}")
|
|
set(CPLUS_INCLUDE_PATH_BACKUP "$ENV{CPLUS_INCLUDE_PATH}")
|
|
_vcpkg_backup_env_variable(LD_LIBRARY_PATH)
|
|
_vcpkg_backup_env_variable(LIBRARY_PATH)
|
|
set(LIBPATH_BACKUP "$ENV{LIBPATH}")
|
|
|
|
# Setup include enviromnent
|
|
set(ENV{INCLUDE} "${_VCPKG_INSTALLED}/include${VCPKG_HOST_PATH_SEPARATOR}${INCLUDE_BACKUP}")
|
|
set(ENV{INCLUDE_PATH} "${_VCPKG_INSTALLED}/include${VCPKG_HOST_PATH_SEPARATOR}${INCLUDE_PATH_BACKUP}")
|
|
set(ENV{C_INCLUDE_PATH} "${_VCPKG_INSTALLED}/include${VCPKG_HOST_PATH_SEPARATOR}${C_INCLUDE_PATH_BACKUP}")
|
|
set(ENV{CPLUS_INCLUDE_PATH} "${_VCPKG_INSTALLED}/include${VCPKG_HOST_PATH_SEPARATOR}${CPLUS_INCLUDE_PATH_BACKUP}")
|
|
|
|
# Setup global flags
|
|
set(C_FLAGS_GLOBAL "$ENV{CFLAGS} ${VCPKG_C_FLAGS}")
|
|
set(CXX_FLAGS_GLOBAL "$ENV{CXXFLAGS} ${VCPKG_CXX_FLAGS}")
|
|
set(LD_FLAGS_GLOBAL "$ENV{LDFLAGS} ${VCPKG_LINKER_FLAGS}")
|
|
if(NOT VCPKG_TARGET_IS_WINDOWS)
|
|
string(APPEND C_FLAGS_GLOBAL " -fPIC")
|
|
string(APPEND CXX_FLAGS_GLOBAL " -fPIC")
|
|
else()
|
|
string(APPEND C_FLAGS_GLOBAL " /D_WIN32_WINNT=0x0601 /DWIN32_LEAN_AND_MEAN /DWIN32 /D_WINDOWS")
|
|
string(APPEND CXX_FLAGS_GLOBAL " /D_WIN32_WINNT=0x0601 /DWIN32_LEAN_AND_MEAN /DWIN32 /D_WINDOWS")
|
|
string(APPEND LD_FLAGS_GLOBAL " /VERBOSE -no-undefined")
|
|
if(VCPKG_TARGET_ARCHITECTURE STREQUAL x64)
|
|
string(APPEND LD_FLAGS_GLOBAL " /machine:x64")
|
|
elseif(VCPKG_TARGET_ARCHITECTURE STREQUAL x86)
|
|
string(APPEND LD_FLAGS_GLOBAL " /machine:x86")
|
|
endif()
|
|
endif()
|
|
|
|
foreach(BUILDTYPE "debug" "release")
|
|
if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL BUILDTYPE)
|
|
if(BUILDTYPE STREQUAL "debug")
|
|
# Skip debug generate
|
|
if (_VCPKG_NO_DEBUG)
|
|
continue()
|
|
endif()
|
|
set(SHORT_BUILDTYPE "-dbg")
|
|
set(CMAKE_BUILDTYPE "DEBUG")
|
|
else()
|
|
# In NO_DEBUG mode, we only use ${TARGET_TRIPLET} directory.
|
|
if (_VCPKG_NO_DEBUG)
|
|
set(SHORT_BUILDTYPE "")
|
|
else()
|
|
set(SHORT_BUILDTYPE "-rel")
|
|
endif()
|
|
set(CMAKE_BUILDTYPE "RELEASE")
|
|
endif()
|
|
|
|
set(WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}${SHORT_BUILDTYPE}")
|
|
|
|
message(STATUS "Building ${TARGET_TRIPLET}${SHORT_BUILDTYPE}")
|
|
|
|
if(_bc_ADD_BIN_TO_PATH)
|
|
set(_BACKUP_ENV_PATH "$ENV{PATH}")
|
|
if(BUILDTYPE STREQUAL "debug")
|
|
vcpkg_add_to_path(PREPEND "${CURRENT_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/debug/bin")
|
|
else()
|
|
vcpkg_add_to_path(PREPEND "${CURRENT_INSTALLED_DIR}/${VCPKG_TARGET_TRIPLET}/bin")
|
|
endif()
|
|
endif()
|
|
|
|
if (CMAKE_HOST_WIN32)
|
|
set(TMP_CFLAGS "${C_FLAGS_GLOBAL} ${VCPKG_C_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
string(REGEX REPLACE "[ \t]+/" " -" TMP_CFLAGS "${TMP_CFLAGS}")
|
|
set(ENV{CFLAGS} ${TMP_CFLAGS})
|
|
|
|
set(TMP_CXXFLAGS "${CXX_FLAGS_GLOBAL} ${VCPKG_CXX_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
string(REGEX REPLACE "[ \t]+/" " -" TMP_CXXFLAGS "${TMP_CXXFLAGS}")
|
|
set(ENV{CXXFLAGS} ${TMP_CXXFLAGS})
|
|
|
|
set(TMP_LDFLAGS "${LD_FLAGS_GLOBAL} ${VCPKG_LINKER_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
string(REGEX REPLACE "[ \t]+/" " -" TMP_LDFLAGS "${TMP_LDFLAGS}")
|
|
set(ENV{LDFLAGS} ${TMP_LDFLAGS})
|
|
|
|
string(REPLACE " " "\ " _VCPKG_INSTALLED_PKGCONF "${CURRENT_INSTALLED_DIR}")
|
|
string(REGEX REPLACE "([a-zA-Z]):/" "/\\1/" _VCPKG_INSTALLED_PKGCONF "${_VCPKG_INSTALLED_PKGCONF}")
|
|
string(REPLACE "\\" "/" _VCPKG_INSTALLED_PKGCONF "${_VCPKG_INSTALLED_PKGCONF}")
|
|
if(BUILDTYPE STREQUAL "debug")
|
|
set(ENV{VCPKG_PKG_PREFIX} ${_VCPKG_INSTALLED_PKGCONF}/debug)
|
|
else()
|
|
set(ENV{VCPKG_PKG_PREFIX} ${_VCPKG_INSTALLED_PKGCONF})
|
|
endif()
|
|
|
|
else()
|
|
set(ENV{CFLAGS} "${C_FLAGS_GLOBAL} ${VCPKG_C_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
set(ENV{CXXFLAGS} "${CXX_FLAGS_GLOBAL} ${VCPKG_CXX_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
|
|
if(BUILDTYPE STREQUAL "debug")
|
|
set(ENV{LDFLAGS} "-L${_VCPKG_INSTALLED}/debug/lib/ -L${_VCPKG_INSTALLED}/debug/lib/manual-link/ ${LD_FLAGS_GLOBAL} ${VCPKG_LINKER_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
set(ENV{LIBRARY_PATH} "${_VCPKG_INSTALLED}/debug/lib/${VCPKG_HOST_PATH_SEPARATOR}${_VCPKG_INSTALLED}/debug/lib/manual-link/${LIBRARY_PATH_PATHLIKE_CONCAT}")
|
|
set(ENV{LD_LIBRARY_PATH} "${_VCPKG_INSTALLED}/debug/lib/${VCPKG_HOST_PATH_SEPARATOR}${_VCPKG_INSTALLED}/debug/lib/manual-link/${LD_LIBRARY_PATH_PATHLIKE_CONCAT}")
|
|
else()
|
|
set(ENV{LDFLAGS} "-L${_VCPKG_INSTALLED}/lib/ -L${_VCPKG_INSTALLED}/lib/manual-link/ ${LD_FLAGS_GLOBAL} ${VCPKG_LINKER_FLAGS_${CMAKE_BUILDTYPE}}")
|
|
set(ENV{LIBRARY_PATH} "${_VCPKG_INSTALLED}/lib/${VCPKG_HOST_PATH_SEPARATOR}${_VCPKG_INSTALLED}/lib/manual-link/${LIBRARY_PATH_PATHLIKE_CONCAT}")
|
|
set(ENV{LD_LIBRARY_PATH} "${_VCPKG_INSTALLED}/lib/${VCPKG_HOST_PATH_SEPARATOR}${_VCPKG_INSTALLED}/lib/manual-link/${LD_LIBRARY_PATH_PATHLIKE_CONCAT}")
|
|
endif()
|
|
endif()
|
|
|
|
if(MAKE_BASH)
|
|
set(MAKE_CMD_LINE "${MAKE_COMMAND} ${MAKE_OPTS}")
|
|
else()
|
|
set(MAKE_CMD_LINE ${MAKE_COMMAND} ${MAKE_OPTS})
|
|
endif()
|
|
vcpkg_execute_build_process(
|
|
COMMAND ${MAKE_BASH} ${MAKE_CMD_LINE}
|
|
WORKING_DIRECTORY "${WORKING_DIRECTORY}"
|
|
LOGNAME "${_bc_LOGFILE_ROOT}-${TARGET_TRIPLET}${SHORT_BUILDTYPE}"
|
|
)
|
|
|
|
if(_bc_ADD_BIN_TO_PATH)
|
|
set(ENV{PATH} "${_BACKUP_ENV_PATH}")
|
|
endif()
|
|
endif()
|
|
endforeach()
|
|
|
|
if (_bc_ENABLE_INSTALL)
|
|
foreach(BUILDTYPE "debug" "release")
|
|
if(NOT DEFINED VCPKG_BUILD_TYPE OR VCPKG_BUILD_TYPE STREQUAL BUILDTYPE)
|
|
if(BUILDTYPE STREQUAL "debug")
|
|
# Skip debug generate
|
|
if (_VCPKG_NO_DEBUG)
|
|
continue()
|
|
endif()
|
|
set(SHORT_BUILDTYPE "-dbg")
|
|
else()
|
|
# In NO_DEBUG mode, we only use ${TARGET_TRIPLET} directory.
|
|
if (_VCPKG_NO_DEBUG)
|
|
set(SHORT_BUILDTYPE "")
|
|
else()
|
|
set(SHORT_BUILDTYPE "-rel")
|
|
endif()
|
|
endif()
|
|
|
|
message(STATUS "Installing ${TARGET_TRIPLET}${SHORT_BUILDTYPE}")
|
|
|
|
if(MAKE_BASH)
|
|
set(MAKE_CMD_LINE "${MAKE_COMMAND} ${INSTALL_OPTS}")
|
|
else()
|
|
set(MAKE_CMD_LINE ${MAKE_COMMAND} ${INSTALL_OPTS})
|
|
endif()
|
|
|
|
set(WORKING_DIRECTORY "${CURRENT_BUILDTREES_DIR}/${TARGET_TRIPLET}${SHORT_BUILDTYPE}")
|
|
vcpkg_execute_build_process(
|
|
COMMAND ${MAKE_BASH} ${MAKE_CMD_LINE}
|
|
WORKING_DIRECTORY "${WORKING_DIRECTORY}"
|
|
LOGNAME "install-${TARGET_TRIPLET}${SHORT_BUILDTYPE}"
|
|
)
|
|
|
|
endif()
|
|
endforeach()
|
|
string(REGEX REPLACE "([a-zA-Z]):/" "/\\1/" _VCPKG_INSTALL_PREFIX "${CURRENT_INSTALLED_DIR}")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}_tmp")
|
|
file(RENAME "${CURRENT_PACKAGES_DIR}" "${CURRENT_PACKAGES_DIR}_tmp")
|
|
file(RENAME "${CURRENT_PACKAGES_DIR}_tmp${_VCPKG_INSTALL_PREFIX}/" "${CURRENT_PACKAGES_DIR}")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}_tmp")
|
|
endif()
|
|
|
|
# Restore enviromnent
|
|
set(ENV{CFLAGS} "${C_FLAGS_BACKUP}")
|
|
set(ENV{CXXFLAGS} "${CXX_FLAGS_BACKUP}")
|
|
set(ENV{LDFLAGS} "${LD_FLAGS_BACKUP}")
|
|
|
|
set(ENV{INCLUDE} "${INCLUDE_BACKUP}")
|
|
set(ENV{INCLUDE_PATH} "${INCLUDE_PATH_BACKUP}")
|
|
set(ENV{C_INCLUDE_PATH} "${C_INCLUDE_PATH_BACKUP}")
|
|
set(ENV{CPLUS_INCLUDE_PATH} "${CPLUS_INCLUDE_PATH_BACKUP}")
|
|
_vcpkg_restore_env_variable(LIBRARY_PATH)
|
|
_vcpkg_restore_env_variable(LD_LIBRARY_PATH)
|
|
|
|
if (CMAKE_HOST_WIN32)
|
|
set(ENV{PATH} "${PATH_GLOBAL}")
|
|
endif()
|
|
|
|
|
|
endfunction()
|