mirror of
https://github.com/microsoft/vcpkg.git
synced 2024-12-11 20:19:01 +08:00
6f7ffeb18f
* [libice] replace macros with typedefs * [libx11] fix dl linkage on linux and cleanup the cmake wrapper. * [libxxf86vm] add port * [libxtst] add port * [libxt] add port * [libxmu] add port * [libxaw] add port * bump port version * v db * fix libxpm and maybe cross libxt * malloc returns null for cross builds * fix typo * fix stuff * v db * fix stuff ? * WIP commit * libxt cross fix * add todo * fix libxaw * xcb add some fixes. * fix todos * fix arm ? * fix path * bump some versions * shorten comment * format manifest * v db * fix stuff * ci baseline * v db * adjust libx11 wrapper again * v db * add license * remove doubled entry from v db * v db * libxmu remove global variable. * correctly split unistd.patch and apply it * disable thread safe init in libx11 on windows * v db * libx11 append options correctly. * v db * still not correct. * v db
68 lines
2.1 KiB
CMake
68 lines
2.1 KiB
CMake
if(VCPKG_TARGET_IS_WINDOWS AND VCPKG_LIBRARY_LINKAGE STREQUAL static)
|
|
list(APPEND PATCHES fix_libiconv.patch)
|
|
endif()
|
|
|
|
vcpkg_from_github(
|
|
OUT_SOURCE_PATH SOURCE_PATH
|
|
REPO KDE/kio
|
|
REF v5.89.0-rc2
|
|
SHA512 08df36c08b028998884983fa233aad5bfc05d4e9e5899ed85390015daa7e0703272edabc59189579957e9971435887c4486796061878ce0f252ac2259b78a799
|
|
HEAD_REF master
|
|
PATCHES
|
|
${PATCHES}
|
|
)
|
|
|
|
vcpkg_check_features(OUT_FEATURE_OPTIONS FEATURE_OPTIONS
|
|
INVERTED_FEATURES
|
|
"kf5notifications" CMAKE_DISABLE_FIND_PACKAGE_KF5Notifications
|
|
"kf5wallet" CMAKE_DISABLE_FIND_PACKAGE_KF5Wallet
|
|
)
|
|
|
|
# Prevent KDEClangFormat from writing to source effectively blocking parallel configure
|
|
file(WRITE "${SOURCE_PATH}/.clang-format" "DisableFormat: true\nSortIncludes: false\n")
|
|
|
|
vcpkg_cmake_configure(
|
|
SOURCE_PATH "${SOURCE_PATH}"
|
|
OPTIONS
|
|
-DCMAKE_FIND_PACKAGE_TARGETS_GLOBAL=ON
|
|
-DBUILD_TESTING=OFF
|
|
-DCMAKE_DISABLE_FIND_PACKAGE_KF5DocTools=ON
|
|
-DCMAKE_VERBOSE_MAKEFILE=ON
|
|
-DKDE_INSTALL_QTPLUGINDIR=plugins
|
|
-DKDE_INSTALL_PLUGINDIR=plugins
|
|
-DKDE_INSTALL_LIBEXECDIR=bin
|
|
${FEATURE_OPTIONS}
|
|
MAYBE_UNUSED_VARIABLES CMAKE_DISABLE_FIND_PACKAGE_KF5Notifications
|
|
)
|
|
|
|
vcpkg_cmake_install()
|
|
vcpkg_cmake_config_fixup(PACKAGE_NAME KF5KIO CONFIG_PATH lib/cmake/KF5KIO)
|
|
vcpkg_copy_pdbs()
|
|
|
|
set(LIBEXEC_TOOLS kio_http_cache_cleaner kiod5 kioexec kioslave5)
|
|
|
|
if(NOT VCPKG_TARGET_IS_WINDOWS)
|
|
if(NOT VCPKG_TARGET_IS_ANDROID)
|
|
list(APPEND LIBEXEC_TOOLS kpac_dhcp_helper)
|
|
endif()
|
|
|
|
list(TRANSFORM LIBEXEC_TOOLS PREPEND "kf5/")
|
|
endif()
|
|
|
|
vcpkg_copy_tools(
|
|
TOOL_NAMES kcookiejar5 ktelnetservice5 ktrash5 protocoltojson ${LIBEXEC_TOOLS}
|
|
AUTO_CLEAN
|
|
)
|
|
|
|
file(APPEND "${CURRENT_PACKAGES_DIR}/tools/${PORT}/qt.conf" "Data = ../../share")
|
|
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/include")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/debug/share")
|
|
|
|
if(VCPKG_LIBRARY_LINKAGE STREQUAL "static")
|
|
file(REMOVE_RECURSE "${CURRENT_PACKAGES_DIR}/bin" "${CURRENT_PACKAGES_DIR}/debug/bin")
|
|
endif()
|
|
|
|
file(GLOB LICENSE_FILES "${SOURCE_PATH}/LICENSES/*")
|
|
vcpkg_install_copyright(FILE_LIST ${LICENSE_FILES})
|